R = QQ[x,y, MonomialOrder => Lex];
I = ideal(y-x^2);
J = ideal(x^2+y^2-1);
K = I + J; 
gb K

R = QQ[x,y,z, MonomialOrder => Lex];
I = ideal(x+y+z -3, x^2 + y^2 + z^2 - 6, x^3 + y^3 + z^3 - 10);
dim I
gb I






--  Binomial Random variable, again

S = QQ[s,t];
R = QQ[p0,p1,p2,p3,p4];
phi1 = map(S,R, matrix{{
s^4,
s^3*t,
s^2*t^2,
s*t^3,
t^4}});
I = kernel phi1;
gb I
mingens I


--  with coefficients

phi2 = map(S,R, matrix{{
s^4,
4*s^3*t,
6*s^2*t^2,
4*s*t^3,
t^4}});
J = kernel phi2;
gb J
mingens J

K = ideal( 4*p0 + 3*p1 + 2*p2 + p3 - 18, p1 + 2*p2 + 3*p3 + 4*p4 - 22);
Maxlike1 = I + K
dim Maxlike1
degree Maxlike1

Maxlike2 = J+K
dim Maxlike2
degree Maxlike2


--  independence model

S = QQ[a1,a2,a3,b1,b2,b3];
R = QQ[p11,p12,p13,p21,p22,p23,p31,p32,p33];
phi = map(S,R,matrix{{
a1*b1,a1*b2,a1*b3,
a2*b1,a2*b2,a2*b3,
a3*b1,a3*b2,a3*b3}});
I = kernel phi;
mingens I


--mixture of independent random variables
S = QQ[a1,a2,a3,b1,b2,b3, c1,c2,c3,d1,d2,d3];
R = QQ[p11,p12,p13,p21,p22,p23,p31,p32,p33];
phi = map(S,R,matrix{{
a1*b1 + c1*d1,
a1*b2 + c1*d2,
a1*b3 + c1*d3,
a2*b1 + c2*d1,
a2*b2 + c2*d2,
a2*b3 + c2*d3,
a3*b1 + c3*d1,
a3*b2 + c3*d2,
a3*b3 + c3*d3}});
I = kernel phi;
mingens I

-- conditional independence model  x1 + x2 | x3,  x1 + x3 | x2
R = QQ[p111,p112,p121,p122,p211,p212,p221,p222];
I1 = ideal(
p111*p221 - p121*p211, p112*p222 - p122*p212);
I2 = ideal(
p111*p212 - p112*p211, p121*p222 - p122*p221);
mymodel = I1 + I2;
ass mymodel
L = ass mymodel;
gb L_0
gb L_1
gb L_2